バンダイ出荷表の更新を通知する Twitter bot を作ってみた

resource "aws_ecr_repository" "get_gunpla_shipment" {
  name = "get_gunpla_shipment"
}

resource "aws_ecr_lifecycle_policy" "get_gunpla_shipment" {
  repository = aws_ecr_repository.get_gunpla_shipment.name

  policy = <<EOF
{
    "rules": [
        {
            "rulePriority": 1,
            "description": "Expire images older than 3 days",
            "selection": {
                "tagStatus": "untagged",
                "countType": "sinceImagePushed",
                "countUnit": "days",
                "countNumber": 3
            },
            "action": {
                "type": "expire"
            }
        }
    ]
}
EOF
}

resource "aws_iam_role" "iam_for_lambda" {
  name                = "iam_for_lambda"
  managed_policy_arns = ["arn:aws:iam::aws:policy/service-role/AWSLambdaBasicExecutionRole"]

  assume_role_policy = <<EOF
{
  "Version": "2012-10-17",
  "Statement": [
    {
      "Action": "sts:AssumeRole",
      "Principal": {
        "Service": "lambda.amazonaws.com"
      },
      "Effect": "Allow",
      "Sid": ""
    }
  ]
}
EOF
}

resource "aws_lambda_function" "get_gunpla_shipment" {
  function_name = "get_gunpla_shipment"
  package_type  = "Image"
  memory_size   = 512
  timeout       = 60
  role          = aws_iam_role.iam_for_lambda.arn
  image_uri     = "653376028258.dkr.ecr.ap-northeast-1.amazonaws.com/get_gunpla_shipment@sha256:b00fda93202cadae15ecb7026a786bc60492017824a96ce1cc1e0fcfbbab4873"
}

resource "aws_cloudwatch_log_group" "get_gunpla_shipment" {
  name              = "/aws/lambda/get_gunpla_shipment"
  retention_in_days = 7
}

resource "aws_cloudwatch_event_rule" "get_gunpla_shipment" {
  name                = "get_gunpla_shipment"
  description         = "Run Lambda get_gunpla_shipment"
  schedule_expression = "cron(0 3 * * ? *)" #daily12:00JST
}

resource "aws_cloudwatch_event_target" "get_gunpla_shipment" {
  rule = aws_cloudwatch_event_rule.get_gunpla_shipment.name
  arn  = aws_lambda_function.get_gunpla_shipment.arn
}

resource "aws_lambda_permission" "allow_cloudwatch_to_run_lambda" {
  statement_id  = "AllowExecutionFromCloudWatch"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.get_gunpla_shipment.function_name
  principal     = "events.amazonaws.com"
  source_arn    = aws_cloudwatch_event_rule.get_gunpla_shipment.arn
}